RETURN expression;

带有表达式的 RETURN 会终止函数，并将 expression 的值返回给调用者。此形式用于不返回集合的 PL/pgSQL 函数。

在返回标量类型的函数中，表达式的结果将自动转换为函数的返回类型，如赋值部分所述。但是要返回复合（行）值，您必须编写一个表达式，提供完全请求的列集。这可能需要使用显式转换。

如果您使用输出参数声明了函数，则只需编写不带表达式的 RETURN。将返回输出参数变量的当前值。

如果您将函数声明为返回 void，则可以使用 RETURN 语句提前退出函数；但请不要在 RETURN 后面编写表达式。

函数的返回值不能未定义。如果控制到达函数顶级块的末尾而没有遇到 RETURN 语句，则会发生运行时错误。但是，此限制不适用于具有输出参数的函数和返回 void 的函数。在这些情况下，如果顶级块完成，则会自动执行 RETURN 语句。

一些示例

-- functions returning a scalar type
RETURN 1 + 2;
RETURN scalar_var;

-- functions returning a composite type
RETURN composite_type_var;
RETURN (1, 2, 'three'::text);  -- must cast columns to correct types

RETURN NEXT expression;
RETURN QUERY query;
RETURN QUERY EXECUTE command-string [ USING expression [, ... ] ];

当声明 PL/pgSQL 函数返回 SETOF sometype 时，遵循的过程略有不同。在这种情况下，要返回的各个项目由一系列 RETURN NEXT 或 RETURN QUERY 命令指定，然后使用不带参数的最终 RETURN 命令来指示该函数已完成执行。RETURN NEXT 可以用于标量和复合数据类型；对于复合结果类型，将返回整个结果的 “表”。RETURN QUERY 将执行查询的结果附加到函数的结果集中。RETURN NEXT 和 RETURN QUERY 可以在单个返回集合的函数中自由混合，在这种情况下，它们的结果将被连接起来。

RETURN NEXT 和 RETURN QUERY 实际上并不从函数返回 — 它们只是将零行或多行附加到函数的结果集中。然后，执行将继续执行 PL/pgSQL 函数中的下一个语句。当连续执行 RETURN NEXT 或 RETURN QUERY 命令时，将构建结果集。最终的 RETURN（不应有参数）会导致控制退出函数（或者您可以让控制到达函数的末尾）。

RETURN QUERY 具有变体 RETURN QUERY EXECUTE，它指定要动态执行的查询。可以通过 USING 将参数表达式插入到计算的查询字符串中，就像在 EXECUTE 命令中一样。

如果您使用输出参数声明了函数，则只需编写不带表达式的 RETURN NEXT。在每次执行时，将保存输出参数变量的当前值，以便最终作为结果的行返回。请注意，您必须将函数声明为返回 SETOF record （当有多个输出参数时），或 SETOF sometype （当只有一个类型为 sometype 的输出参数时），以便创建带有输出参数的返回集合的函数。

以下是使用 RETURN NEXT 的函数示例

CREATE TABLE foo (fooid INT, foosubid INT, fooname TEXT);
INSERT INTO foo VALUES (1, 2, 'three');
INSERT INTO foo VALUES (4, 5, 'six');

CREATE OR REPLACE FUNCTION get_all_foo() RETURNS SETOF foo AS
$BODY$
DECLARE
    r foo%rowtype;
BEGIN
    FOR r IN
        SELECT * FROM foo WHERE fooid > 0
    LOOP
        -- can do some processing here
        RETURN NEXT r; -- return current row of SELECT
    END LOOP;
    RETURN;
END;
$BODY$
LANGUAGE plpgsql;

SELECT * FROM get_all_foo();

以下是使用 RETURN QUERY 的函数示例

CREATE FUNCTION get_available_flightid(date) RETURNS SETOF integer AS
$BODY$
BEGIN
    RETURN QUERY SELECT flightid
                   FROM flight
                  WHERE flightdate >= $1
                    AND flightdate < ($1 + 1);

    -- Since execution is not finished, we can check whether rows were returned
    -- and raise exception if not.
    IF NOT FOUND THEN
        RAISE EXCEPTION 'No flight at %.', $1;
    END IF;

    RETURN;
 END;
$BODY$
LANGUAGE plpgsql;

-- Returns available flights or raises exception if there are no
-- available flights.
SELECT * FROM get_available_flightid(CURRENT_DATE);

IF boolean-expression THEN
    statements
END IF;

IF-THEN 语句是最简单的 IF 形式。如果条件为真，则执行 THEN 和 END IF 之间的语句。否则，跳过它们。

示例

IF v_user_id <> 0 THEN
    UPDATE users SET email = v_email WHERE user_id = v_user_id;
END IF;

IF boolean-expression THEN
    statements
ELSE
    statements
END IF;

IF-THEN-ELSE 语句是对 IF-THEN 的补充，它允许您指定一组替代语句，当条件不为真时（注意这包括条件计算结果为 NULL 的情况）应执行这些语句。

示例

IF parentid IS NULL OR parentid = ''
THEN
    RETURN fullname;
ELSE
    RETURN hp_true_filename(parentid) || '/' || fullname;
END IF;

IF v_count > 0 THEN
    INSERT INTO users_count (count) VALUES (v_count);
    RETURN 't';
ELSE
    RETURN 'f';
END IF;

IF boolean-expression THEN
    statements
[ ELSIF boolean-expression THEN
    statements
[ ELSIF boolean-expression THEN
    statements
    ...
]
]
[ ELSE
    statements ]
END IF;

有时，不仅仅只有两种选择。IF-THEN-ELSIF 提供了一种方便的方法来依次检查多个替代方案。会依次测试 IF 条件，直到找到第一个为真的条件。然后执行关联的语句，之后控制权传递给 END IF 之后的下一个语句。（不会测试任何后续的 IF 条件。）如果没有 IF 条件为真，则执行 ELSE 块（如果有）。

这是一个示例

IF number = 0 THEN
    result := 'zero';
ELSIF number > 0 THEN
    result := 'positive';
ELSIF number < 0 THEN
    result := 'negative';
ELSE
    -- hmm, the only other possibility is that number is null
    result := 'NULL';
END IF;

关键字 ELSIF 也可以拼写为 ELSEIF。

实现相同任务的另一种方法是嵌套 IF-THEN-ELSE 语句，如下例所示

IF demo_row.sex = 'm' THEN
    pretty_sex := 'man';
ELSE
    IF demo_row.sex = 'f' THEN
        pretty_sex := 'woman';
    END IF;
END IF;

但是，这种方法需要为每个 IF 编写一个匹配的 END IF，因此当存在许多替代方案时，使用 ELSIF 要比使用它麻烦得多。

CASE search-expression
    WHEN expression [, expression [ ... ]] THEN
      statements
  [ WHEN expression [, expression [ ... ]] THEN
      statements
    ... ]
  [ ELSE
      statements ]
END CASE;

简单形式的 CASE 提供基于操作数相等性的条件执行。会计算（一次）search-expression，并将其与 WHEN 子句中的每个 expression 依次进行比较。如果找到匹配项，则执行相应的 statements，然后控制权传递给 END CASE 之后的下一个语句。（不会计算后续的 WHEN 表达式。）如果未找到匹配项，则执行 ELSE statements；但是，如果不存在 ELSE，则会引发 CASE_NOT_FOUND 异常。

这是一个简单的例子

CASE x
    WHEN 1, 2 THEN
        msg := 'one or two';
    ELSE
        msg := 'other value than one or two';
END CASE;

CASE
    WHEN boolean-expression THEN
      statements
  [ WHEN boolean-expression THEN
      statements
    ... ]
  [ ELSE
      statements ]
END CASE;

搜索形式的 CASE 提供基于布尔表达式真值的条件执行。依次计算每个 WHEN 子句的 boolean-expression，直到找到一个产生 true 的表达式。然后执行相应的 statements，然后控制权传递给 END CASE 之后的下一个语句。（不会计算后续的 WHEN 表达式。）如果没有找到真值结果，则执行 ELSE statements；但是，如果不存在 ELSE，则会引发 CASE_NOT_FOUND 异常。

这是一个示例

CASE
    WHEN x BETWEEN 0 AND 10 THEN
        msg := 'value is between zero and ten';
    WHEN x BETWEEN 11 AND 20 THEN
        msg := 'value is between eleven and twenty';
END CASE;

除了到达省略的 ELSE 子句会导致错误而不是不执行任何操作的规则外，这种形式的 CASE 与 IF-THEN-ELSIF 完全等效。

[ <<label>> ]
LOOP
    statements
END LOOP [ label ];

LOOP 定义一个无限循环，它会无限期地重复执行，直到被 EXIT 或 RETURN 语句终止。可选的 label 可供嵌套循环中的 EXIT 和 CONTINUE 语句使用，以指定这些语句引用哪个循环。

EXIT [ label ] [ WHEN boolean-expression ];

如果未给定 label，则终止最内层循环，并接下来执行 END LOOP 之后的语句。如果给定了 label，则它必须是当前或某些外部级别的嵌套循环或块的标签。然后终止命名的循环或块，并继续执行循环/块对应的 END 之后的语句。

如果指定了 WHEN，则仅当 boolean-expression 为真时，才会发生循环退出。否则，控制权传递给 EXIT 之后的语句。

EXIT 可以与所有类型的循环一起使用；它不限于与无条件循环一起使用。

当与 BEGIN 块一起使用时，EXIT 将控制权传递给块末尾之后的下一个语句。请注意，必须为此目的使用标签；无标签的 EXIT 永远不会被视为与 BEGIN 块匹配。（这是 PostgreSQL 的 8.4 之前的版本的一个更改，它允许无标签的 EXIT 与 BEGIN 块匹配。）

示例

LOOP
    -- some computations
    IF count > 0 THEN
        EXIT;  -- exit loop
    END IF;
END LOOP;

LOOP
    -- some computations
    EXIT WHEN count > 0;  -- same result as previous example
END LOOP;

<<ablock>>
BEGIN
    -- some computations
    IF stocks > 100000 THEN
        EXIT ablock;  -- causes exit from the BEGIN block
    END IF;
    -- computations here will be skipped when stocks > 100000
END;

CONTINUE [ label ] [ WHEN boolean-expression ];

如果未给定 label，则开始最内层循环的下一次迭代。也就是说，跳过循环体中剩余的所有语句，并将控制权返回给循环控制表达式（如果有），以确定是否需要另一次循环迭代。如果存在 label，则它指定将继续执行的循环的标签。

如果指定了 WHEN，则仅当 boolean-expression 为真时，才开始循环的下一次迭代。否则，控制权传递给 CONTINUE 之后的语句。

CONTINUE 可以与所有类型的循环一起使用；它不限于与无条件循环一起使用。

示例

LOOP
    -- some computations
    EXIT WHEN count > 100;
    CONTINUE WHEN count < 50;
    -- some computations for count IN [50 .. 100]
END LOOP;

[ <<label>> ]
WHILE boolean-expression LOOP
    statements
END LOOP [ label ];

只要 boolean-expression 的计算结果为 true，WHILE 语句就会重复执行一系列语句。在每次进入循环体之前都会检查该表达式。

例如

WHILE amount_owed > 0 AND gift_certificate_balance > 0 LOOP
    -- some computations here
END LOOP;

WHILE NOT done LOOP
    -- some computations here
END LOOP;

[ <<label>> ]
FOR name IN [ REVERSE ] expression .. expression [ BY expression ] LOOP
    statements
END LOOP [ label ];

这种形式的 FOR 创建一个循环，该循环迭代一系列整数值。变量 name 会自动定义为 integer 类型，并且仅存在于循环内部（循环中会忽略变量名称的任何现有定义）。给出范围下限和上限的两个表达式在进入循环时计算一次。如果未指定 BY 子句，则迭代步长为 1，否则为 BY 子句中指定的值，该值同样在循环进入时计算一次。如果指定了 REVERSE，则每次迭代后都会减去而不是加上步长值。

一些整数 FOR 循环的示例

FOR i IN 1..10 LOOP
    -- i will take on the values 1,2,3,4,5,6,7,8,9,10 within the loop
END LOOP;

FOR i IN REVERSE 10..1 LOOP
    -- i will take on the values 10,9,8,7,6,5,4,3,2,1 within the loop
END LOOP;

FOR i IN REVERSE 10..1 BY 2 LOOP
    -- i will take on the values 10,8,6,4,2 within the loop
END LOOP;

如果下限大于上限（或在 REVERSE 情况下小于上限），则根本不执行循环体。不会引发错误。

如果 label 附加到 FOR 循环，则可以使用限定名称（使用该 label）来引用整数循环变量。

异常处理程序通常需要识别发生的特定错误。在 PL/pgSQL 中，有两种方法可以获取有关当前异常的信息：特殊变量和 GET STACKED DIAGNOSTICS 命令。

在异常处理程序中，特殊变量 SQLSTATE 包含与引发的异常对应的错误代码（有关可能的错误代码列表，请参阅 表 A.1）。特殊变量 SQLERRM 包含与异常关联的错误消息。这些变量在异常处理程序之外是未定义的。

在异常处理程序中，还可以使用 GET STACKED DIAGNOSTICS 命令检索有关当前异常的信息，该命令的格式如下：

GET STACKED DIAGNOSTICS variable { = | := } item [ , ... ];

每个 item 都是一个关键字，用于标识要分配给指定 variable 的状态值（该变量应具有接收该值的正确数据类型）。当前可用的状态项在 表 41.2 中显示。

如果异常没有为某个项设置值，则将返回空字符串。

这是一个示例

DECLARE
  text_var1 text;
  text_var2 text;
  text_var3 text;
BEGIN
  -- some processing which might cause an exception
  ...
EXCEPTION WHEN OTHERS THEN
  GET STACKED DIAGNOSTICS text_var1 = MESSAGE_TEXT,
                          text_var2 = PG_EXCEPTION_DETAIL,
                          text_var3 = PG_EXCEPTION_HINT;
END;